CoolBasic Forums

Code: Select all

Const F_Balance = 90   //Määrittää, kuinka nopeasti ääni siirtyy
Const F_Volume = 0.3    //Määrittää, kuinka nopeasti ääni hiljenee
Function Sound1D(sound, x#, y#)
    Dist# = Distance(CameraX(), CameraY(), x, y)
    x = x - CameraX()
    x = x / ScreenWidth() * Balance
    
    PlaySound(sound, Min(100, Max(0, 100 - Dist * F_Volume)), Min(100, Max(-100, x)))
End Function

Code: Select all

//================================================================================
// Äänen soittaminen
//================================================================================
Function PlayGameSound(_sound, _x, _y)
    // Ääntä ei ole olemassa
    If _sound = 0 Then Return 0
    snd = gSounds(_sound)
    
    // Äänenvoimakkuus riippuu etäisyydestä
    volume# = (100 - Max(0, Distance(_x, _y, CameraX(), CameraY()) / 20)) / 100.0 * Float(gFXVolume)
    Return PlaySound(snd, volume)
EndFunction

Code: Select all

SCREEN 1024,768

Type Sound2D
    Field file As String
    Field source As Integer 
    Field sound As Integer 
    Field x As Float
    Field y As Float
    Field vol As Integer 
    Field freq As Integer 
    Field cont As integer 
    Field isPlaying
    Field isLoad 
    Field static 
End Type 

//etäisyyden merkitys yksikköä kohden
// esim jos etäisyys on 100 vaikuttaa se 100*0.3 = 30 yksikköä voimakkuuteen
Const DistanceModifier = 0.3

//kuinka paljon voimakkuuteen etäisyydellä on merkitystä maksimissaan
Const DistanceModifierAmount = 100.0

//kuinka paljon voimakkuuteen kulmalla on merkitystä maksimissaan
Const ListeningAngleModifierAmount = 40.0

//kuuntelupisteen arvot
Global ListeningPointX, ListeningPointY, ListeningAngle, ListenInWorldCoordinates


b = LoadSound("Media\SK_Battle2.mp3")

s = PlayLoadedSound2D(b)

DrawToWorld ON 

ShowMouse OFF

Repeat

    //luodaan staattisia hetkellisiä ääniä
    If MouseHit(1) Then 
        PositionSound2D(PlaySound2D("Media\SK_Battle2.mp3",1,Rand(30,100)),MouseWX(),MouseWY())
    EndIf 
        
 
    a#=Timer()/30.0
    sx# = Cos(a#)*100
    sy# = Sin(a#)*100
    
    PositionSound2D(s, sx, sy)
    
    
    For ss.sound2D = Each sound2D
    
        If ss\static Then Color 0,255,0 Else Color 255,0,0
    
        If ss\isPlaying Then  
            DrawSound(ConvertToInteger(ss))
        EndIf 
    Next ss
    
    Color cbwhite

    lx = MouseWX()
    ly = MouseWY()
    
    Circle lx-2, ly+2,5,1
    Line lx+Cos(la+45)*20, ly+Sin(la+45)*20, lx, ly
    Line lx+Cos(la-45)*20, ly+Sin(la-45)*20, lx, ly

    la = la + MouseMoveZ()*10
    
    ListenIn(lx,ly,la)
    
    
    DrawScreen 

Forever 

//piirtää ääniaaltoja
Function DrawSound(sound,border#=60)
    If sound <> 0 Then 
        s.Sound2D = ConvertToType(sound)
        If s <> NULL Then 
            
            a#=Timer()/15.0
        
            r = GetRGB(RED)
            g = GetRGB(GREEN)
            b = GetRGB(BLUE)
            
            size# = DistanceModifierAmount*(1.0/DistanceModifier)
            
            amount = size#/border#
            
            For i=0 To amount-1
                rad = Int(a#+i*border#) Mod Int(size#)
                
                m# = 1.0-(Float(rad)/size#)
                
                Color r*m#,g*m#,b*m#
                
               // If ListenInWorldCoordinates Then 
                    Circle s\x-rad, s\y+rad,rad*2,0
               // Else 
               //     Circle s\x-rad, s\y-rad,rad*2,0
               // EndIf 
            Next i
            
        EndIf 
            
    EndIf 

End Function 

//kertasoitto tiedostosta
Function PlaySound2D(source$, static = 0, vol=100,freq=-1)

    s.Sound2D = New (Sound2D)
    s\vol = vol
    s\freq = freq
    s\cont = 0
    s\static = static
    s\isload = False 
    s\sound = PlaySound (source$, s\vol)
    s\isPlaying = True

    Return ConvertToInteger(s)
End Function 

//alkaa soittamaan muistiin ladattua ääntä, voi myös toistaa
Function PlayLoadedSound2D(source, static = 0, vol=100,cont=1,freq=-1)

    s.Sound2D = New (Sound2D)
    
    s\source = source
    s\vol = vol
    s\freq = freq
    s\cont = cont
    s\static = static
    s\isload = True 
    s\isPlaying = True 
    s\sound = PlaySound (s\source, s\vol)
    
    Return ConvertToInteger(s)
End Function 

//asettaa kuuntelupisteen ja päivittää staattiset äänet
Function ListenIn(x#=0.0,y#=0.0,ang#=0.0,worldCoordinates=1)
    ListeningPointX = x#
    ListeningPointY = y#
    ListeningAngle = ang#
    ListenInWorldCoordinates = worldCoordinates
    
    For s.sound2D = Each sound2D
        If s\static = 1 And s\isPlaying Then  
    
            UpdateSound2D(ConvertToInteger(s))
    
        EndIf 
    Next s
    
End Function 


// asettaa äänilähteen paikoilleen ja päivittää
// soivan äänen
Function PositionSound2D(sound, x#, y#)
    If sound <> 0 Then 
        s.Sound2D = ConvertToType(sound)
        
        s\x=x#
        s\y=y#
        
        If s\static = 0 Then UpdateSound2D(ConvertToInteger(s))

    EndIf 
End Function 

//päivittää soivan äänen
Function UpdateSound2D(sound)
    If sound <> 0 Then 
        s.Sound2D = ConvertToType(sound)
        
        If SoundPlaying(s\sound) = 0 Then 
        
            If s\cont = 1 And s\isLoad And s\isPlaying Then 
                s\sound = PlaySound (s\source, s\vol)
            Else 
                Delete s
            EndIf 
        EndIf 
        
        If s <> NULL And s\isPlaying Then 
         
            x#=s\x
            y#=s\y
            
            ly# = ListeningPointY
            lx# = ListeningPointX
            
            If ListenInWorldCoordinates Then 
                y#=-y#
                ly#=-ListeningPointY
            EndIf 
            
            ang# = GetAngle(lx#,ly#,x#,y#)
            
            dis# = Distance(lx#,ly#,x#,y#)
            
            fVol# = Min(Cos(ang#-ListeningAngle)*ListeningAngleModifierAmount,0.0) +  s\vol - Min(dis#*DistanceModifier,DistanceModifierAmount)
            
            vol = Min(Max(fVol#,0),100)
            
            position = -Sin(float(ang#-ListeningAngle))*100.0
        
            If s\freq = -1 Then 
                SetSound s\sound, OFF, vol, position
            Else 
                SetSound s\sound, OFF, vol, position, s\freq
            EndIf 
        EndIf 
    EndIf 

End Function