Tyhmät kysymykset (I/2009)

[Nasse-setä]

Miten tilen animointi tapahtuu. Tai miten yleensä tile animointeja käytetään? Manuaalia olen paljon selannut mutta en ole vieläkään hiffannut(tyhmyys?). Kun kartan animoi niin miten se sen tekee? Miten tehdään tilesetti minkä voi animoida? Siis ihan oikeesti koitin useasti manuaalia eli älkää nyt siitä mitään alkako jauhaa. Kysyn siis molemmista tileistä että tilekartoista.

[Jonez]

Kuten varmasti tiedät, kartta animoidaan komennolla PlayObject. Miten kartta sitten tietää mitkä tilet animoida? Jokaisessa editorissa on keino jolla määritellä animodut tilet. Määrittely tapahtuu seuraavasti: valitset tilen jonka haluat animoida, sekä animaation pituuden. Animaation seuraava frame on aina tilesetin seuraava tile.
Tyyliin:

abcdefg
hijklmno
pqrstuvw

valitset tilen "m" ja animaation pituudeksi 2 (tai kolme, saattaa riippua editorista). Näin animaatiossa on kolme framea: m, ensimmäinen frame, esim. TileGenissä järjestysluku 0. N, toinen frame ja o kolmas frame.

Kun kartta tallennetaan, datatiedostoon luonnollisesti kirjoitetaan ylös mitkä tilet ovat animoitu. Voit animoida tilejä myös koodista käsin komennolla SetTile. Periaate on sama: SetTile _tileId, _animPituus, _nopeus

Hiukan muokattu versio cb-oppitunnista #11:

Code: Select all

FrameLimit 40 'rajoita nopeutta

kartta = LoadMap("Media\cdm2.til","Media\tileset.bmp")
PlayObject kartta,0,0,1

ukko = LoadObject ("Media\guy.bmp",72)

SetupCollision ukko, kartta, 1, 4, 2

_data = GetMap2( 0, 10, 10 )
SetTile _data, 5, 1
Repeat

    'Ukon ohjaus
    If LeftKey() Then TurnObject ukko,5
    If RightKey() Then TurnObject ukko,-5
    If UpKey() Then MoveObject ukko,2
    If DownKey() Then MoveObject ukko,-2

    UpdateGame

    CloneCameraPosition ukko

    DrawScreen

Forever

[Nasse-setä]

Kiitti! Kullan arvonen selitys. Sun laisii pitäis olla enemmän!

[mikeful]

Täällä kysytään ohjelmointijuttuja eikä tapella keskenään. Tehkää se yksityisviesteillä tai muilla yksityisillä keinoilla.

[kaneli2000]

Nyt ei enää jaksa. Oon tapellu uuden pelimoottorin ampumisen kanssa jo toista viikkoa. Kysynkin siis: miten kannattaa tehdä ampuminen, kun vihollinen on tehty typellä?

Itse lähdin kehittämään ObjectPick yms. Pick-komennoilla. Ei siitä mitään tullu kun ei taidot riitä :s.

[Character]

Minä tekisin funktioilla. Esim:

Code: Select all

Function VihuAmmu(vihuObj, ammusObj)
	ammus.VIHUNAMMUKSET = New(VIHUNAMMUKSET)
	ammus\Obj = CloneObject(ammusObj)
	CloneobjectPosition ammus\Obj, vihuObj
	CloneObjectOrientation ammus\Obj, vihuObj
EndFunction

Jotenkin noin. Ja sitten kun pitäisi ampua kutsut vain VihuAmmu(vihu\obj, patiobjekti).

Edit: Itse ainakin käytän tuota ja toimii.

[kaneli2000]

Minä tekisin funktioilla. Esim:

Code: Select all

Function VihuAmmu(vihuObj, ammusObj)
	ammus.VIHUNAMMUKSET = New(VIHUNAMMUKSET)
	ammus\Obj = CloneObject(ammusObj)
	CloneobjectPosition ammus\Obj, vihuObj
	CloneObjectOrientation ammus\Obj, vihuObj
EndFunction

Jotenkin noin. Ja sitten kun pitäisi ampua kutsut vain VihuAmmu(vihu\obj, patiobjekti).

Eihä tämä joko a) toimi tai b) ole järkevä, koska a) padin objektiluominen on tyhmää ja b) patiobj olisi pakko olla myös Typellä tehty jonka seurauksena tuota on mahdoton(onko, ei kai?) käyttää, koska kahta For...Each luuppia ei saa(?) yhteen.

EDIT: itse ainakin käytin ja toimii.

Ai? Miten? En ole paljon typeillä leikkinyt ennen, aika newbie olen.

[Character]

Tein pikasen esimerkin. Pitäisi toimia (sori huono kommentointi):

Code: Select all

FrameLimit 40

Type VIHUT
    Field obj
    Field reloadTimer
    Field reloadTime
EndType

Type VIHUNAMMUS
    Field obj
EndType

//Media
pelaaja = LoadObject("Media\soldier.bmp", 72)
PositionObject pelaaja, 100, 100
pati = LoadObject("Media\bullet.bmp")
ShowObject pati, OFF

//luodaan 1 vihu
vihu.VIHUT = New(VIHUT)
vihu\obj = LoadObject("Media\guy.bmp", 72)
vihu\reloadTimer = Timer()
vihu\reloadTime = 500

Repeat
    
    //Ohjaus
    TurnObject pelaaja, (LeftKey() - RightKey()) * 2
    MoveObject pelaaja, (UpKey() - DownKey()) * 2
    
    //Päivitetään vihut
    For vihu.VIHUT = Each VIHUT
        PointObject vihu\obj, pelaaja
        MoveObject vihu\obj, 1
        If Timer() > vihu\reloadTimer + vihu\reloadTime
            VihuAmmu(vihu\obj, pati)
            vihu\reloadTimer = Timer()
        EndIf
    Next vihu
    
    //Päivitetään vihujen ammukset
    PäivitäAmmukset()
    
    DrawScreen
    
Forever

Function VihuAmmu(vihuObj, patiObj)
    ammus.VIHUNAMMUS = New(VIHUNAMMUS)
    ammus\obj = CloneObject(patiObj)
    CloneObjectPosition ammus\obj, vihuObj
    CloneObjectOrientation ammus\obj, vihuObj
EndFunction

Function PäivitäAmmukset()
    For ammus.VIHUNAMMUS = Each VIHUNAMMUS
        MoveObject ammus\obj, 3
    Next ammus
EndFunction

Edit: Voithan aina vaihtaa ne kuviksi. Ja miten niin tyhmää?

[kaneli2000]

Juu, muttakun on tyhmää tehdä padit objekteilla.

[Jonez]

Ei välttämättä, jos vihollisetkin ovat objekteja. Näin voit käyttää kätevästi ObjectsOverlap-funkkaria. Objektit ovat kuitenkin suht. helppokäyttöisiä.

Tein kaksi esimerkkiä, joissa toisessa käytetään ObjectPickiä (äärettömän nopeat luodit), toisessa käytetään objekti-pohjaisia luoteja, jotka nekin kulkevat älyttömän nopeasti. Ideana jälkimmäisessä esimerkissä on systeemi joka takaa että luodit osuvat välttämättä, eivätkä "hyppää" vastustajan yli. Koodit ovat hyvin samanlaisia, erona vain tuo ampumissysteemi.

ObjectPick:

Code: Select all

SCREEN 1024, 768
FrameLimit 40

Type tVihut
    Field cObj
    Field cSpeed As Float
    Field cAngle As Float
EndType

Global gObjLehmä
gObjLehmä = LoadObject( "media\cow.bmp" )
ShowObject gObjLehmä, OFF

pelaaja = LoadObject( "media\guy.bmp", 72 )
floor = MakeImage( ScreenWidth(), ScreenHeight() )
crosshair = LoadImage( "media\crosshair.bmp" )
ShowMouse crosshair

soundBullet = LoadSound( "media\gun 1.wav" )

For i = 1 To 10
    NewEnemy()
Next i

Repeat
    DrawImage floor, 0, 0
    
    RotateObject pelaaja, GetAngle( ObjectX( pelaaja ), ObjectY( pelaaja ), MouseWX(), -MouseWY() )
    

        ObjectPick pelaaja

        reload = reload - 1
        bShoot = False
        If MouseDown( 1 ) And reload <= 0 Then
            reload = 20
            bShoot = True
            PlaySound soundBullet
        EndIf

        For iv.tVihut = Each tVihut

           If bShoot Then
                If PickedObject() = iv\cObj Then
                    iv\cAngle = GetAngle( PickedX(), PickedY(), ObjectX( iv\cObj ), ObjectY( iv\cObj ) )
                    iv\cSpeed = 5
                    DrawToImage floor
                        Color 255, 0, 0
                        For i = 1 To 5
                            Circle PickedX() + ScreenWidth() / 2 + Rand( -7, 7 ), -PickedY() + ScreenHeight() / 2 + Rand( -7, 7 ), Rand( 2, 6 )
                        Next i
                    DrawToScreen
                EndIf
            EndIf
            If iv\cSpeed > 0 Then
                iv\cSpeed = iv\cSpeed - 1
            ElseIf iv\cSpeed <= 0 Then
                iv\cSpeed = 0
            EndIf
            
            If iv\cSpeed <> 0 Then Text 20, 20, iv\cSpeed
            TranslateObject iv\cObj, Cos( iv\cAngle ) * iv\cSpeed, -Sin( iv\cAngle ) * iv\cSpeed
        Next iv

    DrawScreen
Forever

Function NewEnemy()
    nv.tVihut = New( tVihut )
    nv\cObj = CloneObject( gObjLehmä )
    PositionObject nv\cObj, Rand( -ScreenWidth() / 2, ScreenWidth() / 2 ), Rand( -ScreenHeight() / 2, ScreenHeight() / 2 )
    ObjectPickable nv\cObj, 2
EndFunction

ObjectsOverlap:

Code: Select all

SCREEN 1024, 768
FrameLimit 40

Type tVihut
    Field cObj
    Field cSpeed As Float
    Field cAngle As Float
    Field cOsumaX
    Field cOsumaY
EndType

Type tLuodit
    Field cObj
EndType

Global gObjLehmä
gObjLehmä = LoadObject( "media\cow.bmp" )
ShowObject gObjLehmä, OFF

Global gObjLuoti
gObjLuoti = LoadObject( "media\bullet.bmp" )
ShowObject gObjLuoti, OFF

pelaaja = LoadObject( "media\guy.bmp", 72 )
floor = MakeImage( ScreenWidth(), ScreenHeight() )
crosshair = LoadImage( "media\crosshair.bmp" )
ShowMouse crosshair

soundBullet = LoadSound( "media\gun 1.wav" )

For i = 1 To 10
    NewEnemy()
Next i

Repeat
    DrawImage floor, 0, 0
    
    RotateObject pelaaja, GetAngle( ObjectX( pelaaja ), ObjectY( pelaaja ), MouseWX(), -MouseWY() )
    
        reload = reload - 1
        bShoot = False
        If MouseDown( 1 ) And reload <= 0 Then
            reload = 20
            PlaySound soundBullet
            Shoot( ObjectX( pelaaja ), ObjectY( pelaaja ), ObjectAngle( pelaaja ) )
        EndIf
        
        For il.tLuodit = Each tLuodit
            _angle = ObjectAngle( il\cObj )
            bExit = False
            For i = 1 To 20
                TranslateObject il\cObj, Cos( _angle ) * 5, Sin( _angle ) * 5
                For iv.tVihut = Each tVihut
                    If ObjectsOverlap( il\cObj, iv\cObj ) Then
                        iv\cOsumaX = ObjectX( il\cObj )
                        iv\cOsumaY = ObjectY( il\cObj )
                        DeleteObject il\cObj
                        Delete il     
                        bExit = True
                        Exit
                    EndIf
                Next iv
                If bExit = True Then Exit
            Next i
        Next il
        
        For iv.tVihut = Each tVihut
            If iv\cOsumaX <> 0 Or iv\cOsumaY <> 0 Then

                iv\cAngle = GetAngle( iv\cOsumaX, iv\cOsumaY, ObjectX( iv\cObj ), ObjectY( iv\cObj ) )
                iv\cSpeed = 5
                DrawToImage floor
                    Color 255, 0, 0
                    For i = 1 To 5
                        Circle ObjectX( iv\cObj ) + ScreenWidth() / 2 + Rand( -7, 7 ), - ObjectY( iv\cObj ) + ScreenHeight() / 2 + Rand( -7, 7 ), Rand( 2, 6 )
                    Next i
                DrawToScreen

                iv\cOsumaX = 0
                iv\cOsumaY = 0                    
            EndIf

            If iv\cSpeed > 0 Then
                iv\cSpeed = iv\cSpeed - 1
            ElseIf iv\cSpeed <= 0 Then
                iv\cSpeed = 0
            EndIf
            
            If iv\cSpeed <> 0 Then Text 20, 20, iv\cSpeed
            TranslateObject iv\cObj, Cos( iv\cAngle ) * iv\cSpeed, -Sin( iv\cAngle ) * iv\cSpeed
        Next iv

    DrawScreen
Forever

Function Shoot( _x, _y, _angle )
    nl.tLuodit = New( tLuodit )
    nl\cObj = CloneObject( gObjLuoti )
    PositionObject nl\cObj, _x, _y
    RotateObject nl\cObj, _angle
EndFunction
Function NewEnemy()
    nv.tVihut = New( tVihut )
    nv\cObj = CloneObject( gObjLehmä )
    PositionObject nv\cObj, Rand( -ScreenWidth() / 2, ScreenWidth() / 2 ), Rand( -ScreenHeight() / 2, ScreenHeight() / 2 )
EndFunction

[Taatero]

Eihä tämä joko a) toimi tai b) ole järkevä, koska a) padin objektiluominen on tyhmää ja b) patiobj olisi pakko olla myös Typellä tehty jonka seurauksena tuota on mahdoton(onko, ei kai?) käyttää, koska kahta For...Each luuppia ei saa(?) yhteen.

Ai? Miten? En ole paljon typeillä leikkinyt ennen, aika newbie olen.

Kaksi for luuppia saa sisäkkäin, jopa samaan typeen viitaten: esim

For pati.AMMUKSET = Each AMMUKSET
For pati2.AMMUKSET = Each AMMUKSET

-koodia-

Next pati2
Next pati

Ja mieliestäni aloittelijoille objektien käyttö ammuksina on sallittavaa, sillä automaattinen törmäystunnistus madaltaa koodaamisen kynnystä aika tuntuvasti.

[Nassi_Setä]

Törmäsin ongelmaan elvyttäessä jäätynyttä peliäni:olen tehnyt ammukset tyypeillä ja ne ovat kuvia.Kun ammun yhen kudin kerrallaan ja se osuu vihuun
--> vihu kuolee ja ammus tuhoutuu,mutta kun ammun useamman kudin kerrallaan ja joku osuu vihuun niin tulee mystinen mav.Yritin löytää ratkaisua itse ja käytin hakuakin mutta mikään ei auttanut.

[Substance]

Törmäsin ongelmaan elvyttäessä jäätynyttä peliäni:olen tehnyt ammukset tyypeillä ja ne ovat kuvia.Kun ammun yhen kudin kerrallaan ja se osuu vihuun
--> vihu kuolee ja ammus tuhoutuu,mutta kun ammun useamman kudin kerrallaan ja joku osuu vihuun niin tulee mystinen mav.Yritin löytää ratkaisua itse ja käytin hakuakin mutta mikään ei auttanut.

Vaikeaksi menee ilman koodia. Ethän muuten kloonaa joka ammukselle omaa kuvaa?

EDIT:

Objekteilla kannattaa aloittaa, mutta myöhemmin niistä voi olla vain haittaa, kuten minulla vähänkin isoissa projuissa objektit aiheuttavat muille paljon MAVeja. Enpä enää käytäkään objekteja

[skorpioni-cb]

Koodi. Niin kuin sanottu kannattaa tehä objecteilla.

[Nassi_Setä]

Noh tämä on minun ensimmäinen kuvilla toteuttettava peli,kaikki muut pelini ovat objekti-pelejä.
Joten tämä toisi vähän vaihtetua ja osaaminenkin saattaisi karttua.

Törmäsin ongelmaan elvyttäessä jäätynyttä peliäni:olen tehnyt ammukset tyypeillä ja ne ovat kuvia.Kun ammun yhen kudin kerrallaan ja se osuu vihuun
--> vihu kuolee ja ammus tuhoutuu,mutta kun ammun useamman kudin kerrallaan ja joku osuu vihuun niin tulee mystinen mav.Yritin löytää ratkaisua itse ja käytin hakuakin mutta mikään ei auttanut.

Vaikeaksi menee ilman koodia. Ethän muuten kloonaa joka ammukselle omaa kuvaa?

EDIT:

Objekteilla kannattaa aloittaa, mutta myöhemmin niistä voi olla vain haittaa, kuten minulla vähänkin isoissa projuissa objektit aiheuttavat muille paljon MAVeja. Enpä enää käytäkään objekteja

eikö joka kudille muka kloonata oma kuva?

[Jonez]

eikö joka kudille muka kloonata oma kuva?

Ei välttämättä. Voit piirtää yhden kuvan niin monta kertaa kuin haluat, eri kohtiin. Kuva kannattaa kuitenkin kloonata, jos aiot muokata sitä, kuten kääntää, venyttää tai piirtää siihen.

Code: Select all

SCREEN 1024, 768

Dim lehmät( 9, 1 )

kuva = LoadImage( "media\cow.bmp" )

For i = 0 To 9
    lehmät( i, 0 ) = Rand( 0, ScreenWidth() )
    lehmät( i, 1 ) = Rand( 0, ScreenHeight() )
Next i

Repeat
    For i = 0 To 9
        DrawImage kuva, lehmät( i, 0 ), lehmät( i, 1 )     //piirretään "kuva" monta kertaa.
    Next i
    
    DrawScreen
Forever

[Nassi_Setä]

siis joka kerta kun luon uuden kudin niin en kloonaakkaan vaan piirrän?

EDIT:

50.viesti

[TheFish]

siis joka kerta kun luon uuden kudin niin en kloonaakkaan vaan piirrän?

EDIT:

50.viesti

Cb:ssä on muistaakseni mahdollista viitata kuvaan typen kentällä (siis "luoti\kuva = kuva" ei luo uutta kuvaa muistissa, vaan pelkästään viittauksen "kuva":an). Elikkä voit laittaa kuvan ihan normaalisti typen kentäksi, mutta laitat sen vain "="-operaattorilla, etkä käytä cloneimage:a (tai etenkään loadimage:a).

off:
kumma muuten, että olen joutunut kirjoittamaan tuon vain kerran ilmestyvän "kirjoita CoolBasic" testin jo kolmesti. En tosin ole tänne hirveästi postaillut, mutta eikös se ole tarkoitus kirjoittaa vain kerran per tunnus, eikä kerran per posti?

[esa94]

off:
kumma muuten, että olen joutunut kirjoittamaan tuon vain kerran ilmestyvän "kirjoita CoolBasic" testin jo kolmesti. En tosin ole tänne hirveästi postaillut, mutta eikös se ole tarkoitus kirjoittaa vain kerran per tunnus, eikä kerran per posti?

Kerran per login, AFAIK.

[phons]

HIEHEIEHEI!! Pakko käyttää pientä korostusta... Miten on mahdollista: Kun tapoin tuon räiskintä pelin kärpäsiä, niin huomasin mistä MAVi tulee(kiitos myös programmer of DSG) niin eli kuoleman jälkeen, joo, siinä vaiheessa kun komennan DrawGamea! Jotta kuvat ja piirtokomennot ja tekstit piirtyisi alla pyörivän pelin päälle, joten se on välttämämtöntä(jokin toinen tapa!?)... Mutta ihmettelen miten DrawGame voi aiheuttaa MAV:n, testasin tuon sitten perinpohjin. Pistin komennon eteen WaitKey:n ja kun painoin tuli MAV, ja juuri DrawGame:n kohdalla. Understand...?

Edit: Niin minä juuri teinkin.