Väsäsinpäs tässä jonkinlaisen esimerkin. En ikävä kyllä keksinyt, millä kaavalla animaatio-nopeuden pystyisi laskemaan joka kerta oikein riippumatta FPS:stä ja liikkumisnopeudesta eli joudut ns. kovakoodaamaan animaation nopeuden jos jollain muulla ei ole ratkaisua siihen (ongelma liittyy siis PlayObjectiin, ilman objekteja se olisi paljon helpompaa). Idea tässä on aika samanlainen, mitä JATothrim jo sanoikin. Tilen koko on oletuksen 64x64 (koska Zero on aika iso), mutta sitä voi pienentää muuttamalla vakioita TileWidth ja TileHeight. Kaiken pitäisi pyöriä oikein ainakin 16x16 tilekokoon asti (ainakin tasakokoisilla tileillä).
Code: Select all
FrameLimit 30 // Rajoitetaan pelin nopeutta. Tämä lähinnä siksi
// että animaatio pyörii oikeaa nopeutta
Const TileWidth = 64 // Vakioita, jotka määrittävät tilen leveyden ja korkeuden.
Const TileHeight = 64 // Näitä muuttamalla saa ruudukon pienemmäksi. Kaikki laskut
// on siis sidottu näihin vakioihin eikä esim. lukuun 64. Siis
// näitä muuttamalla kaiken pitäisi toimia oikein pienmilläkin tilekoilla
// (olen testannut vain tasakokoisilla tileillä 16x16 asti).
Const IDLE = 0 // Vakioita, jotka helpottavat muistamista. Eli siis, kun haluaa asettaa esim. suunnan oikeaksi voi kirjoittaa
Const VASEN = 1 // "suunta = OIKEA" sen sijaan, että täytyisi muistella, oliko oikea nyt numero 1 vai 2 ("suunta = 1"). Toinen
Const OIKEA = 2 // vaihtoehto olisi käyttää merkkijonomuuttujaa, mutta se menee mielestäni vain sotkuiseksi.
Const LiikkumisNopeus = 2 // Vakio, joka määrää ukon liikkumisnopeuden (animaatio ei toimi oikein muuttamatta AnimaatioNopeutta, jos tätä muuttaa).
Const AnimaationNopeus = 0.4 // Vakio, joka määrää animaation pyörimisnopeuden, jotta animaatio pysähtyy oikeassa kohdassa
zero_oikea = LoadAnimObject("Media\zerorun1.bmp", 47, 51, 0, 13) // Ladataan animoidut objektit ja asetetaan maskiväri
MaskObject zero_oikea, 255, 0, 255
zero_vasen = LoadAnimObject("Media\zerorun2.bmp", 47, 51, 0, 13)
MaskObject zero_vasen, 255, 0, 255
ShowObject zero_vasen, OFF // Piilotetaan vasemmalle juokseva zero
suunta = OIKEA // Alustetaan suunta oikeaksi. Suunta siis muistaa, mihin suuntaan zero katsoo
liiku = IDLE // Alustetaan liiku idleksi. liiku muistaa suunnan, mihin liikutaan (se on siis IDLE, kun ei liikuta).
waypoint_x = 0 // Alustetaan waypoint. Waypoint on siis se kohde, mitä kohti zero lähtee liikkumaan, kun nappia painetaan
waypoint_y = 0
ScreenPositionObject zero_oikea, 2.5*TileWidth, 2.5*TileHeight // Asetetaan zerot keskelle ruudukkoa
ScreenPositionObject zero_vasen, 2.5*TileWidth, 2.5*TileHeight
Repeat
If liiku = IDLE Then // Liikutetaan vain, jos ei olla liikkumassa
If KeyHit(cbkeyLeft) Then
liiku = VASEN
If suunta = OIKEA Then // Jos zero katsoo väärään suuntaan, vaihdetaan suunta
PositionObject zero_vasen, ObjectX(zero_oikea), ObjectY(zero_oikea) // Asetetaan objekti oikeaan kohtaan
ShowObject zero_oikea, OFF
ShowObject zero_vasen, ON
suunta = VASEN
EndIf
waypoint_x = ObjectX(zero_vasen) - TileWidth // Asetetaan waypointin koordinaatit. Zeron pitää tässä tapauksessa liikkuta vasemmalle
waypoint_y = ObjectY(zero_vasen) // eli x-koordinaatin pitää muuttua tilen leveyden verran ja y-koordinaatin pitää pysyä samana
PlayObject zero_vasen, 0, 13, AnimaationNopeus*(64/TileWidth) // Pyöritetään animaatio
ElseIf KeyHit(cbKeyRight) Then // Tehdään kaikki sama toiseen suuntaan
liiku = OIKEA
If suunta = VASEN Then
PositionObject zero_oikea, ObjectX(zero_vasen), ObjectY(zero_vasen)
ShowObject zero_vasen, OFF
ShowObject zero_oikea, ON
suunta = OIKEA
EndIf
waypoint_x = ObjectX(zero_oikea) + TileWidth
waypoint_y = ObjectY(zero_oikea)
PlayObject zero_oikea, 0, 13, AnimaationNopeus*(64/TileWidth)
EndIf
EndIf
If liiku <> IDLE Then // Jos liikutaan johonkin suuntaan
If liiku = VASEN Then
If Distance(ObjectX(zero_vasen), ObjectY(zero_vasen), waypoint_x, waypoint_y) > 2 Then // Jos ei olla tarpeeksi lähellä waypointia, liikuta zeroa
TranslateObject zero_vasen , -LiikkumisNopeus, 0 // Tässä tapauksessa liikutaan vasemmalle eli siksi miinus LiikkumisNopeuden edessä.
Else // Jos ollaan tarpeeksi lähellä, asetetaan objektin koordinaateiksi waypointin koordinaatit
liiku = IDLE
PositionObject zero_vasen, waypoint_x, waypoint_y
EndIf
Else // Kaikki sama toiseen suuntaan oikealle liikkuessa
If Distance(ObjectX(zero_oikea), ObjectY(zero_oikea), waypoint_x, waypoint_y) > 2 Then
TranslateObject zero_oikea , LiikkumisNopeus, 0
Else
liiku = IDLE
PositionObject zero_oikea, waypoint_x, waypoint_y
EndIf
EndIf
EndIf
// Piirretään ruudukko (kuvastaa karttaa)
For i=1 To ScreenWidth()/TileWidth
Line i*TileWidth, 0, i*TileWidth, ScreenHeight()
Next i
For i=1 To ScreenWidth()/TileHeight
Line 0, i*TileHeight, ScreenWidth(), i*TileHeight
Next i
// Tulostetaan koordinaatit
If suunta = VASEN Then
Text 0,0, "X: "+ObjectX(zero_vasen)
Text 0,15, "Y: "+ObjectY(zero_vasen)
Else
Text 0,0, "X: "+ObjectX(zero_oikea)
Text 0,15, "Y: "+ObjectY(zero_oikea)
EndIf
DrawScreen
Forever
